本文對ANSYS施加彎矩扭矩方法做了具體的總結(jié)。

　　通過查找網(wǎng)上的資料，并進行驗證，對此對施加彎矩扭矩方法總結(jié)加以總結(jié)：

　　施加彎矩扭矩的方法其實有很多種方法，在這里介紹其中的5種，并進行比較：

　　1.將矩轉(zhuǎn)換成一對的力偶，直接施加在對應(yīng)的節(jié)點上面。

　　2.在構(gòu)件中心部位建立一個節(jié)點，定義為mass21單元，然后跟其他受力節(jié)點耦合，形成剛性區(qū)域，就是用cerig命令。然后直接加轉(zhuǎn)矩到主節(jié)點，即中心節(jié)點上面。

　　3.使用mpc184單元。是在構(gòu)件中心部位建立一個節(jié)點,跟其他受力節(jié)點分別形成多根剛性梁，從而形成剛性面。最后也是直接加載荷到中心節(jié)點上面，通過剛性梁來傳遞載荷。

　　4.通過rbe3命令。該方法與方法2很接近。

　　5.基于表面邊界法：主要通過定義一個接觸表面和一個目標節(jié)點接觸來實現(xiàn)，彎矩荷載可以通過在目標節(jié)點上用“F”命令施加。

　　對于方法1，通過轉(zhuǎn)換為集中力或均布力，比如施加扭矩，把端面節(jié)點改成柱坐標，然后等效為施加環(huán)向的節(jié)點力;而施加彎矩，可以將力矩轉(zhuǎn)化為端面的剪切均布力;但這種方法比較容易出現(xiàn)應(yīng)力集中現(xiàn)象;

　　方法2，定義局部剛性區(qū)域，施加過程venture講的很詳細，這里就不在贅述。根據(jù)他的例子，我在下面給出了一段命令流。該方法有個不足，它在端面額外的增加了一定的剛度，只能適用于小變形分析。

　　方法3 ，相對方法2來說，采用剛性梁單元，適用范圍更廣一些，對于大應(yīng)變分析也能很好的適用。但在小應(yīng)變分析下，方法2和方法3沒有什么區(qū)別。

　　方法4，定義一個主節(jié)點，施加了分布力面，應(yīng)該說跟實際比較接近一點，但端面的結(jié)果好像不是很理想，結(jié)果有點偏大，在遠離端面處的位置跟實際很符合。

　　方法5，它具體的受力形式有如下兩種：

　　剛性表面邊界(Rigid surface constraint)-認為接觸面是剛性的，沒有變形，和通過節(jié)點耦合命令CERIG比較相似;

　　分布力邊界(Force-distributed constraint)-允許接觸面的變形，和邊界定義命令RBE3相似。

　　使用這種方法，需要用KEYOPT(2) = 2打開接觸單元的MPC(多點接觸邊界)算法，

　　下面針對venture給出的例題，用不同的方法來實現(xiàn)的命令流。

　　方法1不介紹了，方法2：

　　/PREP7

　　ET,1,95

　　ET,2,21

　　KEYOPT,2,3,0

　　R,1,1E-6

　　MP,EX,1,2.01e5

　　MP,PRXY,1,0.3

　　CYLIND,15,10,0,200,0,360,

　　wpro,,90,

　　vsbw,all

　　wpro,,,90

　　vsbw,all

　　WPCSYS,-1,0

　　K,17 , , ,210

　　lsel,s,,,13,16,1

　　lesize,all, , ,8, , , , ,1

　　lsel,s,,,22

　　lesize,all, , ,4, , , , ,1

　　lsel,s, , ,17,20,1

　　lsel,a, , ,26,27,1

　　lsel,a, , ,30,31,1

　　lesize,all, , ,20,0.4, , , ,1

　　alls

　　vmesh,all

　　!!!!!下面一段開始各個方法有所不同，由于前面的建模一樣，后面的例子就不再給出

　　ksel,s,,,17

　　type,2

　　real,1

　　kmesh,all

　　allsel

　　nsel,s,loc,z,200,210

　　npolt

　　CERIG,node(0,0,210),ALL,ALL, , , ,

　　!!!!!CERIG命令定義局部剛性區(qū)域

　　allsel

　　/SOLU

　　f,node(0,0,210),mz,10e5

　　FINISH

　　!!!!!以下一段邊界條件的施加各種方法一樣，后面例子也不再贅述

　　/SOL

　　nsel,s,loc,z,0

　　d,all,all

　　allsel

　　solve

　　方法3：使用MPC184單元定義剛性梁

　　……

　　et,2,184

　　keyopt,2,1,1

　　nsel,s,loc,z,200

　　n,15000 ,0,0,210

　　type,2

　　*get,nnum,node,0,count

　　*get,ND,node,0,num,min

　　*do,i,2,nnum

　　!!!!節(jié)點個數(shù)是nnum，只需要生成nnum個mpc單元

　　E, 15000,ND

　　ND=NDNEXT(ND)

　　*enddo

　　allsel

　　/SOLU

　　f,node(0,0,210),mz,10e5

　　FINISH

　　……

　　方法4：rbe3命令

　　……

　　ET,2,21

　　KEYOPT,2,3,0

　　R,1,1E-6

　　K,17 , , ,210

　　ksel,s,,,17

　　type,2

　　real,1

　　kmesh,all

　　allsel

　　nsel,s,loc,z,200

　　*get,nnum,node,0,count

　　*get,ND,node,0,num,min

　　*dim,sla,array,nnum

　　*dim,sla2,array,nnum

　　*do,i,1,nnum

　　sla(i)=ND

　　sla2(i)=ND

　　ND=NDNEXT(ND)

　　*enddo

　　allsel

　　rbe3,node(0,0,210),all, sla,sla2

　　/SOLU

　　f,node(0,0,210),mz,10e5

　　FINISH

　　……

　　方法5：定義剛性接觸面

　　……

　　n,15000 ,0,0,200

　　MAT,1

　　R,3

　　REAL,3

　　ET,2,170

　　ET,3,175

　　KEYOPT,3,12,5

　　KEYOPT,3,4,1

　　KEYOPT,3,2,2

　　KEYOPT,2,2,0

　　KEYOPT,2,4,111111

　　TYPE,2

　　! Create a pilot node

　　TSHAP,PILO

　　E,15000

　　! Generate the contact surface

　　ASEL,S,,,14

　　ASEL,A,,,19

　　ASEL,A,,,24

　　ASEL,A,,,28

　　CM,_CONTACT,AREA

　　TYPE,3

　　NSLA,S,1

　　ESLN,S,0

　　ESURF

　　ALLSEL

　　allsel

　　/SOLU

　　f,node(0,0,210),mz,10e5

　　FINISH

　　…...