基于表面邊界法主要通過定義一個接觸表面和一個目標節(jié)點接觸來實現(xiàn)，彎矩荷載可以通過在目標節(jié)點上用“F”命令施加。使用這種方法，需要用KEYOPT(2) = 2打開接觸單元的MPC（多點接觸邊界）算法，具體的受力形式有如下兩種：

1. 剛性表面邊界（Rigid surface constraint）－認為接觸面是剛性的，沒有變形，和通過節(jié)點藕合命令CERIG比較相似；
2. 分布力邊界（Force-distributed constraint）－允許接觸面的變形，和邊界定義命令RBE3相似。

　　這種方法和MIDAS中主從節(jié)點原理相似，因此也可以用來傳遞實體單元和梁單元（圖1）、殼單元和梁單元（圖2）之間內(nèi)力。

圖1

圖2

下面的例子通過對一個矩形截面的懸臂梁施加端彎矩來說明分布力邊界的使用方法：

/COM,*********** 用基于表面接觸法施加彎矩 ***********
/PREP7
ET,1,187
*SET,TID,3
*SET,CID,2
ET,CID,174
ET,TID,170
KEYO,TID,2,1               ! 由用戶指定主節(jié)點的邊界條件
KEYO,TID,4,0               ! 主節(jié)點不約束
KEYO,CID,2,2               ! 選擇MPC(多點接觸邊界)算法
KEYO,CID,4,1               ! 可變形的接觸邊界,方法同RBE3命令
KEYO,CID,12,5              ! 選擇接觸表面性質(zhì):總是綁定

MP,EX,1,206E9
MP,PRXY,1,0.3
MP,DENS,1,7850

BLOCK,-0.2,0.2,-0.4,0.4,0,2

ESIZE,0.080
TYPE,1
MAT,1
SMRTSIZE,5
VMESH,ALL

ALLSEL,ALL
*GET,_MAXNODE,NODE,,NUM,MAX
*SET,_NPILOT,_MAXNODE+1
N,_NPILOT,0,0,2           ! 創(chuàng)建主節(jié)點
TYPE,TID
MAT ,CID
REAL,CID
TSHAP,PILO                ! 定義目標元類型為主節(jié)點
E,_NPILOT                 ! 生成目標單元
TSHAP

ASEL,S,LOC,Z,2
TYPE,CID
MAT,1
AMESH,ALL                 ! 生成接觸面單元
!注:要生成正確的接觸對,必須先生成目標元,再生成接觸元
ALLSEL,ALL
EPLOT

NSEL,S,LOC,Z,0
D,ALL,ALL

NSEL,S,NODE,,_NPILOT
F,ALL,MX,1500E3          !對主節(jié)點施加彎矩
ALLSEL,ALL

/SOLU
ANTYPE,0
TIME,1
OUTRES,ALL,LAST
SOLVE

前處理中定義的接觸對如圖3和圖4所示：

圖3

圖4