我想看一级黄色大片_久久亚洲国产精品一区二区_久久精品免视看国产明星_91久久青青青国产免费

您的位置：網站首頁 > Ansys教程

ANSYS地震反應譜分析示例

時間:2008-09-15 11:03:12 來源:
說明：本命令流由基于網上資料修改整理，希望對初學者有用。

/COM,===========================
/COM,ANSYS地震反應譜分析示例
/COM,--Ben基于網上資料修改整理
/COM,--http://www.lubanren.com
/COM,--2007-12-03
/COM,===========================

/PREP7
!定義參數
B=15 !基本尺寸
A1=1000 !第一個面積
A2=1000 !第二個面積
A3=1000 !第三個面積
NMODE=10
!定義截面
ET,1,BEAM4 !二維桿單元
R,1,0.25,0.0052,0.0052,0.5,0.5
!定義材料特性
MP,EX,1,2.0E11
MP,PRXY,1,,0.3
MP,DENS,1,7.8E3
!定義節點
N,1,-B,0,0 
N,2,0,0,0
N,3,-B,0,B
N,4,0,0,B
N,5,-B,0,2*B
N,6,0,0,2*B
N,7,-B,0,3*B
N,8,0,0,3*B
!定義單元
E,1,3
E,2,4
E,3,5
E,4,6
E,3,4
E,5,6
E,5,7
E,6,8
E,7,8
!邊界條件
D,1,ALL,0,,2
FINISH
!靜力分析
/SOLU
D,1,ALL,0,,2
SFBEAM,1,1,PRES,100000,
SFBEAM,3,1,PRES,100000,
SFBEAM,7,1,PRES,100000,
SOLVE
FINISH
ALLSEL
!模態分析
/SOLU
ANTYPE,2
MODOPT,SUBSP,10 !子空間法
MXPAND,10, , ,1
SOLVE
!存儲各模態頻率
*DIM,FRE,,NMODE
*DO,I,1,NMODE
*GET,FRE(I),MODE,I,FREQ ! OBTAIN MODE FREQENCY FOR MODE I
*ENDDO
FINISH
ALLSEL

!計算反應譜數據（依據規范GB50011-2001 第5.1.5條）
!地震影響系數
GRAV=9.81!重力加速度G
TG=0.35 !特性周期
AMAX=0.08!水平地震影響系數最大值
C=0.05 !阻尼比
!
*DIM,A,,NMODE
*DIM,T,,NMODE
*DO,I,1,NMODE
T(I)=1.0/FRE(I)
*ENDDO
R=0.9+(0.05-C)/(0.5+5.0*C)
P1=0.02+(0.05-C)/8
P2=1+(0.05-C)/(0.06+1.7*C)

*DO,I,1,NMODE
*IF,T(I),GE,0.0,AND,T(I),LT,0.1,THEN
A(I)=(0.45+(10.0*P2-4.5)*T(I))*AMAX*GRAV
*ELSEIF,T(I),GE,0.1,AND,T(I),LE,TG
A(I)=P2*AMAX*GRAV
*ELSEIF,T(I),GT,TG,AND,T(I),LE,5*TG
A(I)=(TG/T(I))**R*P2*AMAX*GRAV
*ELSE
A(I)=(P2*0.2**R-P1*(T(I)-5*TG))*AMAX*GRAV
*ENDIF
*ENDDO
!反應譜分析
/SOLU
ANTYPE,SPECTR
SPOPT,SPRS ! 單點反應譜
SED,1,, ! 反應方向為X軸
SVTYP,2 ! 加速度譜

! 反應譜數據
FREQ,FRE(1),FRE(2),FRE(3),FRE(4),FRE(5),FRE(6),FRE(7),FRE(8),FRE(9)
FREQ,FRE(10)  
SV,,A(1),A(2),A(3),A(4),A(5),A(6),A(7),A(8),A(9)
SV,,A(10)

SRSS,0.0,DISP ! 設置震形組合方式
SOLVE  
FINISH

/POST1
SET,LIST
/INPUT,,MCOM!計算反應譜工況
!***************查看反應譜結果******************
ALLSEL,ALL
FINISH

變形云圖