方法1：通過體分割的辦法建立預應力鋼束，然后通過定義降溫荷載來模擬預應力效應。這種方法在張立明編的《ALGOR、ANSYS在橋梁工程中的應用方法與實例》中有一個算例。
命令流如下：
/prep7  
/title,the analysis of the solid beam and prestressed tendon
/DIST,1,1.08222638492,1
/REP,FAST   
*SET,egjx,2e11  
*SET,agjx,60e-4
*SET,ehnt,3.5e10
*SET,xzxs,1.2e-5
*SET,yjl,200000
et,1,link8  
et,2,solid95
r,1,agjx
r,2
mp,ex,1,egjx
mp,prxy,1,0.3   
mp,dens,1,7800  
mp,dens,2,2500  
mp,alpx,1,xzxs  
mp,ex,2,ehnt
mp,prxy,2,0.3   
blc4,,,1,2,30   
/VIEW,1,1,1,1   
/ANG,1  
/AUTO,1
/REP,FAST   
klist,all   
kwpave,6
wpoff,-0.3  
wprot,0,0,90
vsbw,1  
wpoff,0,0,-0.4  
vsbw,2  
wpoff,0,0.4
wprot,0,90  
vsbw,all
wpstyl  
nummrg,all,,,,low   
numcmp,all  
esize,0.3   
klist,all   
llist,all   
lsel,s,,,28,38,10   
latt,1,1,1  
lmesh,all   
allsel,all  
gplot   
vsel,s,,,all
vatt,2,2,2  
mshape,0,3d
mshkey,1
vmesh,all   
finish  
/solu   
dl,3,,all   
dl,16,,all  
dl,23,,all  
dl,2,,uy
dl,15,,uy   
dl,22,,uy   
/AUTO,1
/REP,FAST   
bfl,28,temp,-yjl/(xzxs*egjx*agjx)   
bfl,38,temp,-yjl/(xzxs*egjx*agjx)   
allsel  
acel,,9.8   
solve   
finish  
/post1  
pldisp  
plnsol,s,1

方法二：體線獨立耦合法建立預應力鋼束
命令流如下，并附有命令說明：
/prep7  
*SET,eg,2e5    !鋼束彈模
*SET,ag,140    !鋼束面積
*SET,eh,4e4    !混凝土的彈模
*SET,r0,9345   !曲線鋼束的半徑   
*SET,yyl,200000  !鋼束的預應力大小
et,1,link8       !定于預應力鋼束單元類型為link8
et,2,solid95     !定義混凝土單元類型為solid95
r,1,ag,yyl/eg/ag*1.036258     !定義單元實常數，對于link8單元為鋼束面積、以及鋼束的初始應變（除模擬預應力張拉還會用于應力剛度矩陣的計算） #p#分頁標題#e#  
r,2              !solid95的單元實常數僅為x軸的調整，并且該實常數僅僅在單元坐標系統選擇為1的時候填寫。一般不填。
mp,ex,1,eg       !預應力鋼束單元性質，包括之前定義的彈模，泊松比
mp,prxy,1,0.3   
mp,ex,2,eh       !混凝土單元性質，包括彈模、泊松比  
mp,prxy,2,0.2   
blc4,,,100,200,3000   !定義長方體的長寬高（混凝土塊體）
/view,1,1,1,1         !調整觀察的角度   
/ang,1  
vplot                 !顯示選擇的體  
ksel,all              !選擇所有的關鍵點
klist
*get,kp0,kp,0,num,max !將最大的kp編號存于kp0中，因為事先不知道最大的關鍵點號是多少，所以先要存在kp0中  
lsel,none             !不選擇所有的線
llist   
k,kp0+1,50,160        !定義關鍵點，kp0是已有的最大關鍵點編號。
k,kp0+2,50,160,3000
k,kp0+3,50,800,1500
larc,kp0+1,kp0+2,kp0+3,r0      !將定義的以上三點連成一條圓弧，半徑為r0。kp0+3用于定義圓弧所在面及曲線邊中點  
kdele,kp0+3                    !刪除kp0+3這個關鍵點
klist
llist
*get,line1,line,0,num,min      !將最小的線編號存于line1中，因為line1是最先定義的預應力鋼束   
lsel,s,loc,z,0                 !選擇z、y坐標均為0的線，用于施加約束（該線為右側截面的梁底線）
lsel,r,loc,y,0  
dl,all,,uy                     !對線施加y方向的約束  
lsel,s,loc,z,3000              !選擇左側截面梁底線（即z=3000，而y=0的線）   
lsel,r,loc,y,0  
dl,all,,all                    !對選擇的線施加約束（UX、UY、UZ）#p#分頁標題#e#
allsel,all                     !選擇所有對象  
lsel,s,,,line1                 !選擇線，最小值line1  
latt,1,1,1                     !將單元性質與選擇的、尚未網格化的線聯系起來  
lesize,all,,,50                !線單元劃分的數目
lmesh,all                      !對line1進行分網   
vsel,all                       !選擇所有的體
vlist
vatt,2,2,2                     !給體賦予相應的屬性(混凝土)  
lsel,s,loc,z,0                 !選擇z=0，而y坐標從10到140范圍內的所有的線  
lsel,r,loc,y,10,140
lesize,all,,,8                 !分網數目8  
lsel,s,loc,z,0                 !再次選擇z=0，而不選y坐標從10到140范圍內的所有線  
lsel,u,loc,y,10,140
lesize,all,,,4                 !分網數目為4  
lsel,s,loc,y,0                 !選擇x=0、y=0坐標處的線（僅有一根線被選中）注意這根線是一根分網的掃掠線。
lsel,r,loc,x,0  
lesize,all,,,50                !分網數目為50
vsweep,all                #p#分頁標題#e#     !通過掃掠網格的方法來用單元填充體                       
allsel,all                     !選擇所有的對象  
lsel,s,,,line1                 !選擇line1最小值（預應力鋼絞線）  
nsll,s,1                       !選擇與所選擇的線對應的所有的節點，即鋼絞線上面的節點，因為網格數為50，所以節點總數為51
cm,cmljnod,node                !將鋼絞線節點編組，其組名為cmljnod
*get,max1,node,0,count         !選擇鋼絞線中的節點單元數目，將其賦給變量max1，此變量可以作為*do循環的上界來確定循環的次數  
*dim,ojd,,max1                 !定義數組序列。數組名為ojd，max1為行的范圍  
*dim,jd,,max1                  !定義數組序列。數組名為jd，max1為行的范圍   
*get,nod1,node,0,num,min       !選擇集中最小的節點號，賦給變量nod1，作為*do循環的上界
*SET,ojd(1),nod1               !將nod1的值賦給ojd(1)
*do,i,2,max1                   !do循環，從2到max1
*SET,ojd(i),ndnext(ojd(i-1))   !將ndnext(ojd(i-1))賦給ojd(i)
*enddo                         !結束循環  
allsel,all                     !選擇所有  
nsel,all                     #p#分頁標題#e#  !選擇所有節點
cmsel,u,cmljnod                !不選擇cmljnod，即鋼絞線對應的節點
*do,i,1,max1                   !i從1循環開始到max1
*SET,nod1,ojd(i)               !將ojd(i)賦給nod1
*SET,j,nnear(nod1)             !將nnear(nod1)賦給j，是指ojdi鄰近的節點嗎？nnear()是一個函數，表示選擇最近的節點。  
*SET,jd(i),j                   !將j賦給jd(i)
*enddo                         !結束循環  
nsel,all                       !選擇所有節點
*SET,ji,1                      !將1賦給ji   
*do,i,1,max1                   !i從1到max1
cp,ji,ux,ojd(i),jd(i)          !定義耦合自由度，ji只是隨機設置的耦合編號。ux為耦合節點的x方向的位移。  
cp,ji+1,uy,ojd(i),jd(i)
cp,ji+2,uz,ojd(i),jd(i)
*SET,ji,ji+3                   !ji+3賦給ji
*enddo                         !結束循環
allsel,all                     !選擇所有單元
*SET,ji,                       !將所有的參數刪除（第三項value為空格時標識刪除）
*SET,i,
*SET,max1,  
*SET,nod1,  
*SET,ojd,   #p#分頁標題#e#
*SET,jd,
*SET,j,
*SET,ag,
*SET,eg,
*SET,eh,
*SET,kp0,   
*SET,r0,
*SET,yyl,   
*SET,line1,
finish                          !建模結束，進入求解
/solu
allsel,all
acel,,9.8                       !考慮自重   
solve   
FINISH  
/POST1                          !進入后處理  
pldisp,1
etable,sigi,ls,1
plls,sigi,sigi,1
plnsol,s,1